alpha-quadrant/net-dns/maradns/maradns-2.0.04.ebuild

# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-dns/maradns/Attic/maradns-2.0.01.ebuild,v 1.1 2011/01/24 13:22:58 matsuu Exp $

EAPI="3"
inherit eutils toolchain-funcs

DESCRIPTION="Proxy DNS server with permanent caching"
HOMEPAGE="http://www.maradns.org/"
SRC_URI="http://www.maradns.org/download/${PV%.*}/${PV}/${P}.tar.bz2"
DEADWOOD="deadwood-3.0.05"

LICENSE="as-is"
SLOT="0"
KEYWORDS="~amd64 ~ppc ~sparc ~x86"
IUSE="ipv6"

DEPEND="dev-lang/perl"

src_prepare() {
	sed -i \
		-e "s:PREFIX/man:PREFIX/share/man:" \
		-e "s:PREFIX/doc/maradns-\$VERSION:PREFIX/share/doc/${PF}:" \
		build/install.locations || die
	sed -i \
		-e "s:make:\$(MAKE):g" \
		-e "s:\$(CC):$(tc-getCC):g" \
		build/Makefile.linux || die
	sed -i -e "s:duende.c:duende-ng.c:g" tools/Makefile* || die
	sed -e "/provide dns/d" "${FILESDIR}/maradns.rc6" > "${T}/maradns.rc6" || die
	sed -e "s:maradns:Deadwood:g" "${FILESDIR}/maradns.rc6" > "${T}/deadwood.rc6" || die
	sed -i \
		-e "s:/etc/deadwood:/var/cache/deadwood:g" \
		${DEADWOOD}/doc/dwood3rc || die
}

src_configure() {
	local myconf

	use ipv6 && myconf="${myconf} --ipv6"

	cd utf8 && make || die
	cd ${S}
	./configure ${myconf} || die
}

src_install() {
	dosbin server/maradns || die

	dosbin tcp/zoneserver || die

	dobin tcp/getzone tcp/fetchzone tools/askmara tools/askmara-tcp tools/duende \
		tools/bind2csv2.py || die

	doman doc/en/man/*.[1-9] || die

	dodoc maradns.gpg.key || die
	dodoc 0QuickStart || die
	dodoc doc/en/*.txt || die
	docinto examples; dodoc doc/en/examples/example_* || die

	insinto /etc; newins doc/en/examples/example_mararc mararc || die
	insinto /etc/maradns; newins doc/en/examples/example_csv2 db.example.net || die

	# DEADWOOD install
	dosbin ${DEADWOOD}/src/Deadwood || die
	doman ${DEADWOOD}/doc/Deadwood.1 || die

	diropts -m775 -o maradns -g maradns
	keepdir /var/cache/deadwood || die
	keepdir /etc/maradns/logger || die
	insinto /etc; newins ${DEADWOOD}/doc/dwood3rc dwood3rc || die

	newinitd "${T}"/deadwood.rc6 deadwood || die
	newinitd "${T}"/maradns.rc6 maradns || die
	newinitd "${FILESDIR}"/zoneserver.rc6 zoneserver || die
}

pkg_setup() {
	enewgroup maradns 99
	enewuser duende 66 -1 -1 maradns
	enewuser maradns 99 -1 -1 maradns
}