JarJar version bump.

dev-java/jarjar/Manifest

@@ -0,0 +1,2 @@
+DIST jarjar-src-1.0rc8.zip 136130 RMD160 76f3231a72a495dd18273bb60489f5c6f7b2a641 SHA1 74b2d7a6801eddc0d1dcc5ad8d02271e58c6d490 SHA256 350b721052ffda3069551e11490be5e65ca93a27b6d0642ca5d153f9d073389a
+EBUILD jarjar-1.0.ebuild 1426 RMD160 d726f573ee25c9534995f0444d6ca7e3ee68fe73 SHA1 97a3ae9b2149c76ee28ff02e2e71df4b7a9b8d1c SHA256 707ee026f8f3cc4ff2f6d5e638c2bd6ba1eea7959a827c15420a810a1c0e05c7

dev-java/jarjar/jarjar-1.0.ebuild

@@ -0,0 +1,58 @@
+# Copyright 1999-2009 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: $
+
+EAPI="2"
+JAVA_PKG_IUSE="doc source test"
+
+inherit java-pkg-2 java-ant-2
+
+DESCRIPTION="Tool for repackaging third-party jars."
+HOMEPAGE="http://code.google.com/p/jarjar/"
+# 1.0 has no source tarball, but there are no changes from 1.0rc8 to 1.0 anyway
+SRC_URI="http://${PN}.googlecode.com/files/${PN}-src-${PV}rc8.zip"
+
+LICENSE="Apache-2.0"
+SLOT="1"
+KEYWORDS="~amd64"
+IUSE=""
+
+COMMON_DEP="dev-java/ant-core:0"
+RDEPEND=">=virtual/jre-1.5
+	${COMMON_DEP}"
+DEPEND=">=virtual/jdk-1.5
+	app-arch/unzip:0
+	dev-java/asm:3
+	dev-java/maven-plugin-api:2.1
+	test? (
+		dev-java/junit:0
+		dev-java/ant-junit:0
+	)
+	${COMMON_DEP}"
+
+S="${WORKDIR}/${P}rc8"
+
+java_prepare() {
+	# bug #191378
+	epatch "${FILESDIR}/0.9-bootclasspath.patch"
+	# bug #305929
+	epatch "${FILESDIR}/1.0-ant-1.8-compat.patch"
+
+	cd lib/ && rm * || die
+	java-pkg_jar-from ant-core
+	java-pkg_jar-from --build-only asm-3 asm.jar asm-3.1.jar
+	java-pkg_jar-from --build-only asm-3 asm-commons.jar asm-commons-3.1.jar
+	java-pkg_jar-from --build-only maven-plugin-api-2.1
+	use test && java-pkg_jar-from --build-only junit
+}
+
+src_test() {
+	ANT_TASKS="ant-junit" eant test
+}
+
+src_install() {
+	java-pkg_newjar "dist/${PN}-snapshot.jar" "${PN}.jar"
+	java-pkg_register-ant-task
+	use doc && java-pkg_dojavadoc dist/javadoc
+	use source && java-pkg_dosrc src/main/com
+}