new version forked-daapd-0.17

media-sound/forked-daapd/Manifest

@@ -2,4 +2,6 @@ AUX forked-daapd-0.12-configure.patch 1979 RMD160 16bbc89a5cc24707ef48d7c5f2d256
 AUX forked-daapd-0.12-libevent.patch 1920 RMD160 27954e9e44f7e4f846f68ee5556dbf78a1b236b1 SHA1 e1118ad1d752e06b76ce3225dd446044e09b4f97 SHA256 331873f0a4bc43b2201a952a9e8c60698c57c0cbe553947776a173ec2ff03259
 AUX forked-daapd.init.d 1275 RMD160 62adf7e4d7ff84725d2f10cbcc140f80eb4095e7 SHA1 9326a2400f8ae76131a25246e396dd00662ca474 SHA256 6861f37fea94e8b36638a4c15856f449593e389dc4bff6aa1f65db7d1beea5de
 DIST forked-daapd-0.16.tar.gz 625910 RMD160 ccd55c08b2857e39bb68bd28cefa92e5f7212527 SHA1 5478cce18cc0b3aad204f4bcbe1f58530d08fa1d SHA256 005ffa56ae15a6800bff8a8d7d5558d9b41e4503daef0338f242d7434b752d4c
+DIST forked-daapd-0.17.tar.gz 628033 RMD160 22bff6f590a7dd2876f12b8a9ad17e3cc0b08043 SHA1 2b58ad71270518e3b92e2cd39ef5a06cdf86a62b SHA256 700a2db8edcc2ec6ca7b369b986e3ac625b57234b16ef5a5e4ac569232a48b55
 EBUILD forked-daapd-0.16.ebuild 2029 RMD160 50c50a48c5e76cfbf14d056297a3692a5fcb86cf SHA1 1aeafadbb9ceb125d42059497ee926ad1c9c9dc6 SHA256 d09e1085801cbb4446d56c003b3156bae458334699d5c7b1d2614c55313c2ca6
+EBUILD forked-daapd-0.17.ebuild 2029 RMD160 50c50a48c5e76cfbf14d056297a3692a5fcb86cf SHA1 1aeafadbb9ceb125d42059497ee926ad1c9c9dc6 SHA256 d09e1085801cbb4446d56c003b3156bae458334699d5c7b1d2614c55313c2ca6

media-sound/forked-daapd/forked-daapd-0.17.ebuild

@@ -0,0 +1,79 @@
+# Copyright 1999-2010 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: $
+
+EAPI="2"
+
+inherit eutils autotools
+
+DESCRIPTION="DAAP and RSP media server. It is a complete rewrite of mt-daapd (Firefly Media Server)."
+HOMEPAGE="http://www.technologeek.org/projects/daapd/index.html"
+SRC_URI="http://alioth.debian.org/~jblache/forked-daapd/${PN}-${PV}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="flac itunes musepack"
+
+RDEPEND="itunes? ( >=app-pda/libplist-0.16 )
+	dev-db/sqlite:3[unlock-notify,threadsafe]
+	>=dev-libs/antlr-c-3.1.3
+	>=dev-libs/avl-0.3.5
+	dev-libs/confuse
+	dev-libs/libevent
+	dev-libs/libgcrypt
+	>=dev-libs/libunistring-0.9.3
+	dev-libs/mini-xml
+	media-libs/alsa-lib
+	flac? ( media-libs/flac )
+	musepack? ( media-libs/taglib )
+	>=net-dns/avahi-0.6.24
+	>=sys-libs/zlib-1.2.5-r2
+	virtual/ffmpeg"
+
+DEPEND="${RDEPEND}
+	dev-java/antlr:3
+	dev-util/gperf
+	dev-util/pkgconfig"
+
+RESTRICT="primaryuri"
+
+src_prepare() {
+	epatch "${FILESDIR}"/${PN}-0.12-configure.patch
+	epatch "${FILESDIR}"/${PN}-0.12-libevent.patch
+	eautoreconf
+}
+
+src_configure() {
+	econf $(use_enable flac) \
+		$(use_enable itunes)\
+		$(use_enable musepack)
+}
+
+src_install() {
+	emake DESTDIR="${D}" install || die "emake install failed."
+
+	newinitd "${FILESDIR}/${PN}.init.d" ${PN} || die
+	keepdir /etc/forked.daapd.d /var/cache/forked-daapd || die
+	mv "${D}/etc/forked-daapd.conf" "${D}/etc/forked.daapd.d/" || die
+
+	dodoc AUTHORS ChangeLog README NEWS || die
+}
+
+pkg_preinst() {
+	enewgroup daapd
+	enewuser daapd -1 -1 /dev/null daapd
+	fowners -R daapd:daapd /etc/forked.daapd.d
+	fowners -R daapd:daapd /var/cache/forked-daapd
+	fperms -R 0700 /etc/forked.daapd.d
+	fperms -R 0700 /var/cache/forked-daapd
+}
+pkg_postinst() {
+	einfo
+	elog "If you want to start more than one ${PN} service, symlink"
+	elog "/etc/init.d/${PN} to /etc/init.d/${PN}.<name>, and it will"
+	elog "load the data from /etc/${PN}.d/<name>.conf."
+	elog "Make sure that you have different cache directories for them."
+	einfo
+}
+