From ff53ffd51521c4a92c90c70b4680fd916cf10248 Mon Sep 17 00:00:00 2001
From: Micha Glave <gentoo@migmedia.de>
Date: Mon, 30 Nov 2020 17:28:54 +0100
Subject: [PATCH] added font-manager from
 https://github.com/PF4Public/gentoo-overlay,

---
 app-misc/font-manager/Manifest                |  2 +
 .../font-manager/font-manager-0.8.0.ebuild    | 66 +++++++++++++++++++
 2 files changed, 68 insertions(+)
 create mode 100644 app-misc/font-manager/Manifest
 create mode 100644 app-misc/font-manager/font-manager-0.8.0.ebuild

diff --git a/app-misc/font-manager/Manifest b/app-misc/font-manager/Manifest
new file mode 100644
index 0000000..90ec3ac
--- /dev/null
+++ b/app-misc/font-manager/Manifest
@@ -0,0 +1,2 @@
+DIST font-manager-0.8.0.tar.gz 2895747 BLAKE2B b8970cf9f94b917ab9ee1b1d1c07a1d0236d1d409d2c17a7acf1c2a1c95abb2e971f678807828fc9502acddf14b181887901b9d7fb5c96d1c8e23165a185973f SHA512 dfde12dbdfcbbd6aaa3c99e4bf2b054ea908c5873d9cf1bb47f273d4d4545dd17168588aa2763bb5c5433cc4450b131900586e9ef9a0fec814cc86eabfaf2aa5
+EBUILD font-manager-0.8.0.ebuild 1526 BLAKE2B fc51acd6f3a099a016f9d4ffb7a9dec1042a24c885d8621c3e7ba6d16439aecf050af814825ecc22bf042fef3bb5e8ecd8e32785c65866f47c00b1109a2d4d4b SHA512 c21ff6ec2c4989634d841f424e3bb0bfcd3c2878099de114a001054d8c48ea60b1a4647f4a0de12caba2fc6cf1d0a468ea32841661279bb72d2f1d2b8641fdd8
diff --git a/app-misc/font-manager/font-manager-0.8.0.ebuild b/app-misc/font-manager/font-manager-0.8.0.ebuild
new file mode 100644
index 0000000..f749824
--- /dev/null
+++ b/app-misc/font-manager/font-manager-0.8.0.ebuild
@@ -0,0 +1,66 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+inherit gnome2 meson vala
+
+if [[ ${PV} = *9999* ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/FontManager/font-manager.git"
+	SRC_URI=""
+else
+	SRC_URI="https://github.com/FontManager/font-manager/archive/${PV}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="amd64 x86"
+fi
+
+DESCRIPTION="A simple font management application for Gtk+ Desktop Environments"
+HOMEPAGE="https://fontmanager.github.io"
+
+VALA_MIN_API_VERSION=0.44
+VALA_USE_DEPEND="vapigen"
+
+LICENSE="GPL-3"
+SLOT="0"
+IUSE="doc gnome-search-provider +manager nautilus nemo reproducible thunar +viewer +nls"
+
+RDEPEND="gnome-base/gnome-common
+	>=dev-db/sqlite-3.8
+	>=dev-libs/json-glib-0.15
+	>=dev-libs/libxml2-2.9
+	>=media-libs/fontconfig-2.1
+	>=media-libs/freetype-2.5
+	>=net-libs/libsoup-2.62
+	>=net-libs/webkit-gtk-2.24
+	>=x11-libs/gtk+-3.22
+	>=x11-libs/pango-1.4
+	nautilus? ( gnome-base/nautilus )
+	nemo? ( gnome-extra/nemo )
+	thunar? ( xfce-base/thunar )
+"
+
+DEPEND="${RDEPEND}
+	$(vala_depend)
+	doc? ( app-text/yelp-tools )
+"
+
+src_prepare() {
+	default
+	vala_src_prepare
+	gnome2_src_prepare
+}
+
+src_configure() {
+	meson_src_configure \
+		$(meson_use manager) \
+		$(meson_use viewer) \
+		$(meson_use reproducible) \
+		$(meson_use nautilus) \
+		$(meson_use nemo) \
+		$(meson_use thunar) \
+		$(meson_use gnome-search-provider search-provider) \
+		$(meson_use nls enable-nls) \
+		$(meson_use doc yelp-doc) \
+		$(meson_use doc gtk-doc) \
+		--buildtype=release
+}