# Copyright 1999-2005 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

inherit eutils flag-o-matic kde subversion

DESCRIPTION="The open source answer to WhereIsIt and Google Desktop Search"
HOMEPAGE="http://kat.sourceforge.net/"
ESVN_REPO_URI="svn://anonsvn.kde.org/home/kde/trunk/playground/base/kat"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~x86 ~amd64 ~alpha ~ppc ~sparc"
IUSE="ext-doc ext-gnumeric ext-html ext-koffice ext-kpresenter ext-kspread
 ext-kword ext-mail ext-openoffice ext-pdf ext-ppt ext-ps ext-rtf ext-tex
 ext-xls xattr"

RDEPEND=">=dev-db/sqlite-3.2.1
	( || ( kde-base/kcontrol kde-base/kdebase ) )
	ext-doc?	( app-text/antiword )
	ext-gnumeric?	( app-office/gnumeric )
	ext-html?	( app-text/html2text )
	ext-koffice?	( app-text/koffice )
	ext-kpresenter?	( app-office/kpresenter )
	ext-kspread?	( app-office/kspread )
	ext-kword?	( app-office/kword )
	ext-mail?	( net-mail/mhonarc )
	ext-openoffice?	( virtual/ooo )
	ext-pdf?	( app-text/xpdf )
	ext-ppt?	( app-text/xlhtml )
	ext-ps?		( app-text/pstotext )
	ext-rtf?	( app-text/unrtf )
	ext-tex?	( dev-tex/untex )
	ext-xls?	( app-text/xlhtml )
	xattr?		( sys-apps/attr )"

DEPEND="${RDEPEND}
	>=sys-devel/autoconf-2.59
	>=sys-devel/automake-1.6
	!kde-misc/kat"

need-kde 3.3

src_unpack() {
	ESVN_UPDATE_CMD="svn update -N" ESVN_FETCH_CMD="svn checkout -N" ESVN_REPO_URI=`dirname ${ESVN_REPO_URI}` subversion_src_unpack

	# Fetch the admin directory of KDE 3.5
	ESVN_REPO_URI="svn://anonsvn.kde.org/home/kde/branches/KDE/3.5/kde-common/admin" subversion_src_unpack

	ESVN_UPDATE_CMD="svn up kat"
	subversion_src_unpack
	
	cd ${S}
	make -f Makefile.cvs
}

src_compile() {
	# Filter fvisibility for now due to compile errors.
	filter-flags -fvisibility-inlines-hidden -fvisibility=hidden 

	# KAT SVN uses newer autoconf and automake 
	export WANT_AUTOCONF=2.5
	export WANT_AUTOMAKE=1.6

	# Unset Unsermake as not all users want unsermake installed
	export UNSERMAKE=no

	PREFIX="`kde-config --prefix`"
	kde_src_compile
}

pkg_postinst() {
	if [ ! -e /dev/inotify ] ; then
		eerror "Your kernel does not seem to have inotify support enabled."
		eerror "In order to enable support for Kat's autoupdate deamon,"
		eerror "I suggest you install the latest sys-kernel/gentoo-sources"
		eerror "(or any other kernel with the inotify patch included)."
		eerror ""
		eerror "Enable Inotify file change notification support (INOTIFY)"
		eerror "within the kernel under Device Drivers / Character Devices."
		eerror "For more information: http://beaglewiki.org/Inotify_Kernel."
		ebeep 10
	fi

	if [ IUSE=xattr ] ; then
		einfo "You selected support for Extented attributes within Kat."
		einfo "You will need to set extended attributes on the file"
		einfo "systems that the autoupdate deamon of Kat is indexing."
		einfo "(Has to be supported by the kernel e.g. EXT2_FS_XATTR,"
		einfo "EXT3_FS_XATTR or REISERFS_FS_XATTR)"
		einfo ""
		einfo "To set extended attributes, you add 'user_xattr' to the"
		einfo "relevant file systems in your /etc/fstab file. For example:"
		einfo "/dev/hda3    /home   ext3        defaults,user_xattr   1 2"
		ebeep 10
	fi
}